| Is a part of release: | Morg |
| File size: | 16784 |
| md5: | 47a328c6cdd7155c0b39423f569be4b5 |
0 REM USR !@ RESTORE OR ~# THEN CLS STR$ LLIST THEN INPUT <>USR !@ RESTORE OR ~+ THEN CLS STR$ LLIST THEN INPUT <> LPRINT W OR MERGE PRINT MERGE LLIST %IN RESTORE ~ MOVE |% NEW } VERIFY o8| AND g REM LET MOVE STR$ PAPER <>
1 REM CODE @ MERGE OR MERGE LLIST ~ PRINT $ CLS OR ! THEN D(! RESTORE ~$ IF MOVE STR$ NEW % LET w CLS STR$ MOVE STEP !Xd COPY GO SUB VAL X! X LPRINT GO SUB VAL !d COPY GO SUB VAL <>VAL
3 DEF FN a(A,b,c,d,e,f)=USR (VAL "23777"+FN Q())
4 DEF FN Q()=VAL "23755"-PEEK VAL "23635"-VAL "256"*PEEK VAL "23636"
10 PRINT AT 0,0
11 LOAD ""CODE
40 DEF FN c(a,b,c)=a*24+b*4+c+64355
45 DEF FN b(a,b,c)=PEEK FN c(a,b,c)
50 DEF FN g(a,b)=a*12+b*2+64222
55 DEF FN h(a,b)=PEEK FN g(a,b)+PEEK (FN g(a,b)+1)*256
60 DEF FN j(a,b)=a*12+b*2+64114
65 DEF FN k(a,b)=PEEK FN j(a,b)+PEEK (FN j(a,b)+1)*256
70 DEF FN l(c)=c*2+62180
80 PAPER 0: INK 7: BRIGHT 1
90 DATA "n ","s ","e ","o ","nord","sud ","est ","oves","vai ","pren","lasc","ucci","atta","amma","colp","dai ","porg","offr","sali","scal","arra","rema","scen","lega","lanc","tira","scoc","affe","stri","aggr","spog","togl","indo","mett","acce","aiut","help","abba","inve","guar"
95 DIM c$(40,4)
100 FOR x=1 TO 40
105 READ a$
110 LET c$(x)=a$
120 NEXT x
130 DATA "lancia ","fibra ","ramo ","lepre ","pagaia ","costola","arco ","freccia","liana ","pietra ","ascia ","vestiti","fascina"
135 DIM e$(13,7)
140 FOR x=1 TO 13
145 READ a$
150 LET e$(x)=a$
155 NEXT x
160 POKE 23606,88: POKE 23607,251
170 POKE 23624,3
180 POKE 23658,8
200 REM iniz2
210 DATA 5,3,5,3,2,2,200,100,100,100,1,6,100,100,5,4,7,6,8,3,100,100,100,100,7,5
220 RESTORE 210
230 FOR x=62182 TO 62207
240 READ y
250 POKE x,y
260 NEXT x
270 LET inve=0
275 LET a=5: LET c=3
280 LET tyrano=1: LET ptero=1: LET sent=1
285 LET pirox=5: LET piroy=2: LET end=0
290 LET indo=0: LET fuoc=0: LET morte=0
295 GO SUB 6000
300 REM introd
310 INPUT "Cosa devo fare?", LINE r$
320 IF LEN r$=0 THEN GO TO 310
330 GO SUB 400
340 PRINT '"->";r$
350 LET ind=1
360 IF c$(ind)=v$ THEN GO TO 600
370 IF ind=40 THEN PRINT "Scusa, ma non ti capisco": GO TO 310
380 LET ind=ind+1
390 GO TO 360
400 REM separa
410 LET o$=""
412 FOR x=1 TO LEN r$
413 LET y=CODE r$(x TO x)
414 IF y>=65 AND y<=90 THEN LET y=y+32
415 LET o$=o$+CHR$ (y)
416 NEXT x
417 LET r$=o$
418 LET o$=""
420 IF r$(1 TO 1)<>" " THEN GO TO 450
430 IF (LEN (r$))=0 THEN LET v$=" ": RETURN
440 LET r$=r$(x+1 TO LEN r$): GO TO 420
450 LET x=1
455 IF r$(x TO x)=" " OR r$(x TO x)="'" OR x=LEN r$ THEN GO TO 470
460 LET x=x+1: GO TO 455
470 LET v$=r$(1 TO x)
480 IF LEN v$>4 THEN LET v$=v$(1 TO 4): GO TO 500
485 IF LEN v$=4 THEN GO TO 500
490 FOR y=LEN v$ TO 3
495 LET v$=v$+" ": NEXT y
500 IF x=LEN r$ THEN RETURN
510 LET x=x+1
515 IF NOT (r$(x TO x)=" " OR r$(x TO x)="'") THEN GO TO 530
520 IF x=LEN r$ THEN RETURN
525 GO TO 510
530 LET o$=r$(x TO LEN r$)
535 LET x=1: LET a$=""
540 IF o$(x TO x)=" " OR o$(x TO x)="'" THEN GO TO 560
545 LET a$=a$+o$(x TO x)
550 IF x<>LEN o$ THEN LET x=x+1: GO TO 540
560 IF a$="su" OR a$="alla" OR a$="all" OR a$="il" OR a$="lo" OR a$="la" OR a$="i" OR a$="gli" OR a$="le" OR a$="l" OR a$="nela" OR a$="a" OR a$="dalla" OR a$="sulla" OR a$="ad" THEN LET o$=o$(x TO LEN o$)
570 IF NOT (o$(1 TO 1)=" " OR o$(1 TO 1)="'") THEN GO TO 580
573 IF LEN o$<=1 THEN LET o$="": RETURN
576 LET o$=o$(2 TO LEN o$): GO TO 570
580 IF LEN o$>7 THEN LET o$=o$(1 TO 7): RETURN
585 IF LEN o$=7 THEN RETURN
590 FOR y=LEN o$ TO 6
593 LET o$=o$+" ": NEXT y
596 RETURN
600 GO SUB ((PEEK (ind+64343))*100)
610 IF morte=1 THEN GO TO 8000
620 IF end>0 THEN GO TO 8050
630 LET v$="": GO TO 310
1000 REM nord
1010 IF FN b(a,c,1)<>1 THEN PRINT "Non puoi andare a nord": RETURN
1020 LET a=a-1
1030 GO SUB 6000
1040 RETURN
1200 REM sud
1210 IF FN b(a,c,2)<>1 THEN PRINT "Non puoi andare a sud": RETURN
1220 LET a=a+1
1230 GO SUB 6000
1240 IF NOT (a=6 AND c=6) THEN RETURN
1250 IF tyrano=1 THEN PRINT "Tyrano ti vede:ti balza addosso e ti uccide.": LET morte=1
1270 RETURN
1400 REM est
1410 IF FN b(a,c,3)<>1 THEN PRINT "Non puoi andare a est": RETURN
1420 LET c=c+1
1430 GO SUB 6000
1440 RETURN
1600 REM ovest
1610 IF FN b(a,c,4)<>1 THEN PRINT "Non puoi andare a ovest": RETURN
1620 LET c=c-1
1630 GO SUB 6000
1640 IF a=8 AND c=5 THEN GO TO 1700
1650 IF NOT (a=7 AND c=2) THEN RETURN
1660 IF fuoc=1 THEN RETURN
1670 PRINT "E' troppo buio: incespichi e batti la testa."
1680 LET morte=1: RETURN
1700 IF sent=1 THEN PRINT "La sentinella ti vede e ti uccide.": LET morte=1
1720 RETURN
1800 REM vai
1810 IF o$="n " OR o$="nord " THEN GO TO 1000
1820 IF o$="s " OR o$="sud " THEN GO TO 1200
1830 IF o$="e " OR o$="est " THEN GO TO 1400
1840 IF o$="o " OR o$="ovest " THEN GO TO 1600
1860 PRINT "Non ho capito dove vuoi andare"
1870 RETURN
2000 REM prendi
2010 IF o$<>"lepre " THEN GO TO 2030
2020 IF PEEK 62188=200 AND a=2 AND c=1 THEN PRINT "La lepre fugge veloce": RETURN
2030 GO SUB 6500
2040 IF ind=0 THEN RETURN
2050 LET y=PEEK FN l(ind): LET z=PEEK (FN l(ind)+1)
2060 IF NOT (a=y AND c=z) THEN PRINT "Non e' qui": RETURN
2070 IF inve=5 THEN PRINT "Hai gia' troppa roba": RETURN
2080 IF o$<>"costola" THEN GO TO 2100
2090 IF ptero=1 THEN PRINT "Lo pterodattilo ti assale: con una beccata ti uccide.": LET morte=1: RETURN
2100 POKE FN l(ind),0: POKE (FN l(ind)+1),0
2110 LET inve=inve+1
2115 PRINT "Prendi ";o$
2120 RETURN
2200 REM lascia
2210 GO SUB 6600
2220 IF ind=0 THEN RETURN
2230 IF ind=-1 THEN PRINT "Non l'hai con te": RETURN
2240 LET inve=inve-1
2250 POKE FN l(ind),a: POKE (FN l(ind)+1),c
2260 PRINT "Lasci ";e$(ind)
2270 RETURN
2400 REM uccidi
2410 IF o$<>"tyrano " THEN GO TO 2480
2415 IF NOT (a=5 AND c=6) THEN PRINT "Non e' qui": RETURN
2420 GO SUB 6700
2425 IF ind<=0 THEN RETURN
2430 IF o$="freccia" THEN GO TO 2460
2435 IF o$<>"arco " THEN PRINT "Non e' adatto": RETURN
2440 LET o$="freccia": GO SUB 6600
2445 IF ind=-1 THEN PRINT "Non hai niente da lanciare": RETURN
2450 GO TO 2470
2460 LET o$="arco ": GO SUB 6600
2465 IF ind=-1 THEN PRINT "Non hai niente per tirarla": RETURN
2470 PRINT "La freccia colpisce il tiranno- sauro in un occhio e lo uccide."
2473 LET tyrano=0: LET inve=inve-1
2476 POKE 62196,100: POKE 62197,100: RETURN
2480 IF o$<>"lepre " THEN GO TO 2530
2485 IF NOT (a=2 AND c=1) THEN PRINT "Non e' qui": RETURN
2490 GO SUB 6700
2495 IF ind<=0 THEN RETURN
2500 IF o$<>"lancia " THEN PRINT "Non e' adatto": RETURN
2505 PRINT "La lancia trafigge la lepre, chemuore."
2510 POKE 62182,100: POKE 62183,100
2515 POKE 62188,2: POKE 62189,1
2520 LET inve=inve-1: RETURN
2530 IF NOT (o$="sentine" OR o$="guardia") THEN PRINT "Non puoi farlo": RETURN
2535 IF NOT (a=8 AND c=6) THEN PRINT "Non e' qui": RETURN
2540 GO SUB 6700
2545 IF ind<=0 THEN RETURN
2550 IF o$<>"ascia " THEN PRINT "Non e' adatto": RETURN
2555 PRINT "L'ascia colpisce alla testa la sentinella, che stramazza."
2560 LET sent=0
2565 POKE 62202,101: POKE 62203,101
2570 LET inve=inve-1
2575 RETURN
2600 REM dai
2610 IF o$="" THEN PRINT "Specifica cosa dovrei dare": RETURN
2620 GO SUB 6600
2630 IF ind=0 THEN RETURN
2640 IF ind=-1 THEN PRINT "Non l'hai con te": RETURN
2650 IF NOT (a=1 AND c=6) THEN GO TO 2700
2660 IF o$<>"lepre " THEN PRINT "Non lo interessa": RETURN
2670 PRINT "Lo pterodattilo divora la lepre e si ammansisce"
2680 LET ptero=0: LET inve=inve-1
2685 POKE 62188,100: POKE 62189,100
2690 RETURN
2700 IF NOT (a=4 AND c=4) THEN GO TO 2750
2710 IF o$<>"ramo " THEN PRINT "Non lo interessa": RETURN
2720 PRINT "Il falegname prende il ramo e lolavora, trasformandolo in pagaia"
2730 LET inve=inve-1
2735 POKE 62186,100: POKE 62187,100
2740 POKE 62190,4: POKE 62191,4
2745 RETURN
2750 IF NOT (a=4 AND c=2) THEN PRINT "Non c'e' nessuno a cui dare qualcosa": RETURN
2760 IF o$<>"fascina" THEN PRINT "Non lo interessa": RETURN
2770 PRINT "Lo stregone prende la fascina, poi si prostra, adorando il fuoco."
2780 LET end=1
2790 RETURN
2893 LET inven=inven-1: POKE 62194,0: POKE 62195,0
2900 REM sali
2910 IF NOT (o$="piroga " OR o$="barca ") THEN GO TO 3000
2920 IF NOT (a=pirox AND c=piroy) THEN PRINT "Non e' qui": RETURN
2930 PRINT "Sali sulla piroga"
2940 LET a=6: LET pirox=0: LET piroy=0
2950 GO SUB 6800
2960 RETURN
3000 IF o$<>"montagn" THEN GO TO 3050
3010 IF NOT (a=2 AND c=6) THEN PRINT "Non puoi farlo": RETURN
3020 PRINT "Scali la piccola montagna"
3030 LET a=1
3040 GO SUB 6800: RETURN
3050 IF o$<>"parete " THEN PRINT "Non puoi farlo": RETURN
3060 IF NOT (a=7 AND c=4) THEN GO TO 3010
3070 PRINT "Scali la parete rocciosa"
3080 LET c=3
3090 GO SUB 6800
3100 RETURN
3200 REM rema
3205 LET a$=o$
3210 LET o$="pagaia "
3220 GO SUB 6600
3225 LET o$=a$
3230 IF ind=-1 THEN PRINT "Non hai niente per remare": RETURN
3240 IF NOT (o$="est " OR o$="e ") THEN GO TO 3270
3250 IF FN b(a,c,3)<>2 THEN PRINT "Non puoi remare a est": RETURN
3260 LET c=c+1: GO TO 6000
3270 IF NOT (o$="ovest " OR o$="o ") THEN GO TO 3300
3280 IF FN b(a,c,4)<>2 THEN PRINT "Non puoi remare a ovest": RETURN
3290 LET c=c-1: GO TO 6000
3300 IF o$="nord " OR o$="n " THEN PRINT "Non puoi remare a nord": RETURN
3310 IF o$="sud " OR o$="s " THEN PRINT "Non puoi remare a sud": RETURN
3320 PRINT "Che direzione sarebbe ";o$;"?"
3330 RETURN
3500 REM scendi
3510 IF NOT (o$="piroga " OR o$="barca ") THEN GO TO 3650
3520 IF pirox<>0 THEN PRINT "Non sei sulla piroga": RETURN
3530 IF c<>1 THEN GO TO 3600
3540 LET a=7
3550 LET pirox=7: LET piroy=1
3560 PRINT "Scendi dalla piroga"
3570 GO SUB 6800
3580 RETURN
3600 IF c=2 THEN LET a=5: LET pirox=5: LET piroy=2: GO TO 3560
3610 IF c<>5 THEN PRINT "Non si puo' sbarcare qui": RETURN
3620 LET a=5
3630 LET pirox=5: LET piroy=5
3640 GO TO 3560
3650 IF o$<>"montagn" THEN GO TO 3700
3660 IF NOT (a=1 AND c=6) THEN PRINT "Non puoi farlo": RETURN
3670 PRINT "Scendi dalla piccola montagna"
3680 LET a=2
3690 GO SUB 6800: RETURN
3700 IF o$<>"parete " THEN PRINT "Da cosa dovrei scendere?!": RETURN
3710 IF NOT (a=7 AND c=3) THEN GO TO 3660
3720 PRINT "Scendi dalla parete rocciosa"
3730 LET c=4
3740 GO SUB 6800
3750 RETURN
3800 REM lega
3810 IF o$<>"albero " THEN GO TO 3850
3820 GO SUB 6700
3825 IF ind<=0 THEN RETURN
3830 IF o$<>"liana " THEN PRINT "Non puoi farlo": RETURN
3840 GO TO 3960
3850 GO SUB 6600
3855 IF ind=0 THEN RETURN
3860 IF ind=-1 THEN PRINT "Non puoi farlo": RETURN
3870 IF o$<>"fibra " THEN GO TO 3900
3875 GO SUB 6900: IF ind<=0 THEN RETURN
3880 IF o$<>"costola" THEN PRINT "Non puoi farlo": RETURN
3885 PRINT "Leghi la fibra vegetale alla costola: ora possiedi un arco."
3890 POKE 62184,100: POKE 62185,100: POKE 62192,100: POKE 62193,100
3893 POKE 62194,0: POKE 62195,0
3895 LET inve=inve-1
3896 RETURN
3900 IF o$<>"costola" THEN GO TO 3930
3905 GO SUB 6700
3910 IF ind<=0 THEN RETURN
3915 IF o$<>"fibra " THEN PRINT "Non puoi farlo": RETURN
3920 GO TO 3885
3930 IF o$<>"liana " THEN PRINT "Non puoi farlo": RETURN
3940 GO SUB 6900: IF o$="albero " THEN GO TO 3960
3950 IF ind<=0 THEN RETURN
3960 IF NOT (a=7 AND c=1) THEN PRINT "Non ci sono alberi a cui sia possibile legare la liana": RETURN
3965 PRINT "Leghi la liana all'albero"
3970 POKE 62198,100: POKE 62199,100
3980 LET inve=inve-1
3990 RETURN
4000 REM lancia
4010 GO SUB 6600
4015 IF ind=0 THEN RETURN
4020 IF ind=-1 THEN PRINT "Non l'hai con te": RETURN
4030 IF o$<>"lancia " THEN GO TO 4070
4040 GO SUB 7000
4045 IF ind<=0 THEN RETURN
4050 IF NOT (o$="lepre " AND a=2 AND c=1) THEN PRINT "Non puoi farlo": RETURN
4060 GO TO 2505
4070 IF o$<>"freccia" THEN GO TO 4100
4075 GO SUB 7000
4080 IF ind<=0 THEN RETURN
4085 IF NOT (o$="tyrano " AND a=5 AND c=6) THEN PRINT "Non puoi farlo": RETURN
4090 GO TO 2460
4100 IF o$<>"ascia " THEN GO TO 4200
4110 GO SUB 7000
4115 IF ind<=0 THEN RETURN
4120 IF NOT ((o$="sentine" OR o$="guardia") AND a=8 AND c=6) THEN PRINT "Non puoi farlo": RETURN
4130 GO TO 2555
4200 IF o$<>"pietra " THEN PRINT "Non puoi farlo": RETURN
4210 GO SUB 7000
4220 IF ind<=0 THEN RETURN
4230 IF NOT (o$="scimmia" AND a=9 AND c=1) THEN PRINT "Non puoi farlo": RETURN
4240 PRINT "Lanci la pietra contro la scimmia. questa, indispettita. ti tira l'ascia di pietra."
4250 POKE 62200,100: POKE 62201,100
4260 POKE 62202,9: POKE 62203,1
4265 LET inve=inve-1
4270 RETURN
4300 REM afferra
4310 IF o$<>"liana " THEN PRINT "Non puoi farlo": RETURN
4320 IF NOT (a=7 AND c=1 AND PEEK 62198=100) THEN PRINT "Non puoi farlo": RETURN
4330 PRINT "Ti aggrappi alla liana e scivolifino in fondo al precipizio."
4340 PRINT "La liana resta troppo alta per poterla raggiungere di nuovo."
4350 LET a=8
4360 GO TO 6800
4500 REM spoglia
4510 IF NOT (a=8 AND c=5) THEN PRINT "Non c'e' nessuno da spogliare": RETURN
4520 IF NOT (o$="sentine" OR o$="guardia") THEN PRINT "Specifica meglio": RETURN
4530 IF PEEK 62204<>100 THEN PRINT "Lo hai gia' fatto": RETURN
4540 PRINT "Togli i vestiti alla sentinella."
4550 POKE 62204,8: POKE 62205,5
4560 GO TO 6800
4600 REM togli
4610 GO SUB 6500
4620 IF ind=0 THEN RETURN
4630 IF o$<>"vestiti" THEN PRINT "Non puoi farlo": RETURN
4640 IF PEEK 62204=0 AND indo=1 THEN PRINT "Ti togli i vestiti": LET indo=0: RETURN
4650 LET o$="sentine"
4660 GO TO 4500
4800 REM indossa
4810 GO SUB 6600
4820 IF ind=0 THEN RETURN
4830 IF ind=-1 THEN PRINT "Non l'hai con te": RETURN
4840 IF o$<>"vestiti" THEN PRINT "Non puoi farlo": RETURN
4850 PRINT "Indossi i vestiti della guardia."
4860 LET indo=1: RETURN
5000 REM accendi
5010 GO SUB 6600
5020 IF ind=0 THEN RETURN
5030 IF ind=-1 THEN PRINT "Non l'hai con te": RETURN
5040 IF o$<>"fascina" THEN PRINT "Non puoi farlo": RETURN
5050 IF NOT (a=8 AND c=4) THEN PRINT "Non c'e' fuoco qui": RETURN
5060 PRINT "Accendi la fascina."
5070 IF indo=1 THEN LET fuoc=1: RETURN
5080 PRINT "La gente del villaggio ti vede eti riconosce come nemico. Ti assalgono e ti uccidono."
5090 LET morte=1: RETURN
5200 REM aiuto
5210 IF a=1 AND c=6 THEN PRINT "Dovresti cercare di farti amico lo pterodattilo.": RETURN
5220 IF pirox=0 THEN PRINT "Non puoi certo remare con le mani!": RETURN
5230 IF a=4 AND c=4 THEN PRINT "Il falegname potrebbe aiutarti, ma gli serve il materiale.": RETURN
5240 IF a=5 AND c=6 THEN PRINT "Non puoi spuntarla in uno scontro diretto: colpiscilo da lontano.": RETURN
5250 IF a=7 AND c=1 THEN PRINT "Forse e' possibile calarsi fin giu': cerca qualcosa di adatto.": RETURN
5260 IF a=7 AND c=3 THEN PRINT "Non e' prudente avventurarsi al buio.": RETURN
5270 IF a=8 AND c=4 THEN PRINT "Non lasceranno prendere il fuocoad un estraneo. Cerca di assomi-gliare ad uno del villaggio.": RETURN
5280 IF a=8 AND c=6 THEN PRINT "Assali la sentinella di sorpresao ti uccidera'.": RETURN
5290 IF a=9 AND c=1 THEN PRINT "Cerca di provocare la scimmia.": RETURN
5300 PRINT "Non ho consigli da darti": RETURN
5500 REM abbandona
5510 PRINT #1;"Sei sicuro di volere abbandonare (s/n)?"
5515 IF INKEY$="" THEN GO TO 5515
5520 IF INKEY$="S" THEN GO TO 8070
5530 RETURN
5700 REM inventario
5710 PRINT "Hai con te:"
5720 FOR x=1 TO 13
5730 IF PEEK FN l(x)<>0 THEN GO TO 5800
5740 PRINT e$(x);
5750 IF x<>12 THEN GO TO 5770
5760 IF indo=1 THEN PRINT " messi";
5765 GO TO 5790
5770 IF x<>13 THEN GO TO 5790
5780 IF fuoc=1 THEN PRINT " accesa";
5790 PRINT
5800 NEXT x
5810 RETURN
6000 REM guarda
6010 CLS
6020 LET x=FN h(a,c)
6030 LET b=FN a(0,0,10,32,1,53521)
6040 IF x=0 THEN GO TO 6050
6045 LET b=FN a(1,8,8,16,1,x)
6050 PRINT AT 10,0
6060 LET y=FN k(a,c)
6070 FOR x=y TO y+63
6080 PRINT CHR$ PEEK x;
6090 NEXT x
6100 PRINT
6110 IF a=7 AND c=1 AND PEEK 62198=100 THEN PRINT "All'albero e' legata una liana."
6115 IF a=pirox AND c=piroy THEN PRINT "Sul fiume c'e' una piroga."
6120 IF a=9 AND c=1 AND PEEK 62202=100 THEN PRINT "Ha in mano un'ascia di pietra."
6125 IF a=8 AND c=6 AND sent=1 THEN PRINT "Vedi una sentinella."
6127 IF a=8 AND c=5 AND sent=0 THEN PRINT "Il corpo della sentinella giace a terra."
6130 IF a=2 AND c=1 AND PEEK 62188=200 THEN PRINT "Una lepre salta tra l'erba."
6135 IF a=6 AND c=6 AND tyrano=0 THEN PRINT "La carcassa di tyrano giace a terra."
6140 PRINT "- Uscite a ";
6150 IF FN b(a,c,1)=1 OR FN b(a,c,1)=2 THEN PRINT " nord";
6160 IF FN b(a,c,2)=1 OR FN b(a,c,2)=2 THEN PRINT " sud";
6170 IF FN b(a,c,3)=1 OR FN b(a,c,3)=2 THEN PRINT " est";
6180 IF FN b(a,c,4)=1 OR FN b(a,c,4)=2 THEN PRINT " ovest";
6190 PRINT '"- Vedi:"
6200 FOR x=1 TO 13
6210 LET y=PEEK FN l(x): LET z=PEEK (FN l(x)+1)
6220 IF NOT (a=y AND c=z) THEN GO TO 6300
6230 PRINT e$(x);
6240 IF x<>13 THEN GO TO 6280
6250 IF fuoc<>1 THEN GO TO 6280
6260 PRINT " accesa";
6280 PRINT
6300 NEXT x
6310 RETURN
6500 REM oggetto
6510 LET ind=1
6520 IF e$(ind)=o$ THEN RETURN
6530 IF ind=13 THEN PRINT "Non so cosa sia un ";o$: LET ind=0: RETURN
6540 LET ind=ind+1
6550 GO TO 6520
6600 REM possesso
6610 GO SUB 6500
6620 IF ind=0 THEN RETURN
6630 LET y=PEEK FN l(ind)
6640 LET z=PEEK (FN l(ind)+1)
6650 IF y=0 THEN RETURN
6660 LET ind=-1
6670 RETURN
6700 REM domanda
6710 INPUT "Con cosa?", LINE r$
6720 IF LEN r$=0 THEN GO TO 6710
6725 PRINT r$
6730 GO SUB 400
6740 IF NOT (v$="con " OR v$="usa " OR v$="util" OR v$="col " OR v$="coll") THEN PRINT "Spiegati meglio": GO TO 6710
6750 GO SUB 6600
6760 IF ind=-1 THEN PRINT "Non l'hai con te"
6770 RETURN
6800 REM inkey
6805 PRINT '">Premi un tasto<"
6810 IF INKEY$="" THEN GO TO 6810
6820 GO SUB 6000
6830 RETURN
6900 REM doman
6910 INPUT "A cosa?", LINE r$
6920 IF LEN r$=0 THEN GO TO 6910
6925 PRINT r$
6930 GO SUB 400
6940 IF NOT (v$="a " OR v$="ad " OR v$="all " OR v$="alla") THEN PRINT "Spiegati meglio": GO TO 6910
6950 IF o$="albero " THEN RETURN
6960 GO SUB 6600
6970 IF ind=-1 THEN PRINT "Non l'hai con te"
6980 RETURN
7000 REM domand
7010 INPUT "Contro chi o cosa?", LINE r$
7020 IF LEN r$=0 THEN GO TO 7010
7025 PRINT r$
7030 GO SUB 400
7040 IF v$<>"cont" THEN PRINT "Spiegati meglio": GO TO 7010
7070 RETURN
8000 REM morte
8010 PRINT '"Sei morto. La tua tribu' non potra' avere il fuoco.": GO TO 8070
8050 REM fine
8060 IF end=1 THEN PRINT '"Ce l'hai fatta. Col fuoco la tuatribu' potra' incamminarsi sullastrada della civilta'."
8070 BEEP .4 TO ,10: PRINT #1;"Un'altra partita (s/n)?"
8080 IF INKEY$="" THEN GO TO 8080
8090 IF INKEY$<>"S" THEN STOP
8100 GO TO 200
50085(n s e o nordsud est ovesvai prenlascucciattaammacolpdai porgoffrsaliscalarraremascenlegalanctirascocaffestriaggrspogtoglindomettacceaiuthelpabbainveguar SAVE [M] OR `lancia fibra ramo lepre pagaia costolaarco freccialiana pietra ascia vestitifascina RANDOMIZE aNPOINT nv RESTORE acTAN yran LOAD VAL ter LOAD COS en POKE VAL iro SAVE VAL iro RANDOMIZE RNDn DATA POINT nd LOAD INKEY$uo READ TAB ort RESTORE zPOINT n DATA &AlRabbandonaOVabba
