СОВЕРШЕННЫЕ МЕТОДЫ КОДИНГА И СОВРЕМЕННЫЕ
СПОСОБЫ РАБОТЫ С ГРАФИКОЙ
Год за годом на SPECCY организуются
новые группы, пишутся программы. Это озна-
чает, что где-то появляются все новые и
новые музыканты, художники и конечно-же
программисты, которые стремятся сделать
что-то интересное, доселе невиданное и
не превзойденное. Где-то сидят будущие
RST#7'ые, IMP'ы, STALKER'ы... Изучают ас-
семблер, днями и ночами, вооружившись STS'
ом, разбирают по кирпичикам программы сво-
их предшественников.
Чтобы помочь всем им, чтобы сэкономить
недели и месяци которые нам приходилось
просиживать за листингами программ, то и
дело отбиваясь от вездесущих глюков, вы-
думывая то, что уже многим давно известно,
делая то, что еще недавно считалось невоз-
можным и подготовлен следующий материал.
В нем собраны разноплановые советы по ко-
дингу, от совсем элементарных процедур, до
более сложных и эффективных.
Предыдущий вариант этого текста уже
однажды публиковался в электронном журнале
"Depth 1", который не получил достаточного
распостранения. Здесь же Вы видите его до-
полненный вариант. Я собираюсь продолжить
данную тему в следующих номерах, описывая
полезные процедуры и методы кодинга.
Итак, перейдем собственно к теме...
1. Рассмотрим наиболее часто используемые
методы вывода изображений на экран.
а).Самый простой способ вывести спрайт -
перебрасывать его последовательно
байт за байтом, строку за строкой.
прорамма, выполняющая такие действия,
выглядит примерно так:
LOOP1 PUSH BC
PUSH HL
LOOP2 LD A,(DE)
INC DE
LD (HL),A
INC L
DJNZ LOOP2
POP HL
CALL DOWN_HL
POP BC
DEC C
JR NZ,LOOP1
RET
DE-адрес спрайта в памяти,
HL-адрес в экране,
B -ширина спрайта в знакоместах,
C -высота спрайта в пикселях.
DOWN_HL - переход на строку ниже.
Данный способ, несмотря на свою простоту
и примитивность, вполне подходит для вы-
вода статичной (неподвижной) графики.
Изменив входные параметры в регистрах
HL,DE,BC, можно вывести картинку любого
размера в любое место экрана. К сожале-
нию, такая гибкость не свойственна всем
остальным способам вывода графики.
б). Выводить графику с фиксированной
шириной.
LOOP1 PUSH DE
LDI ; колличество зависит
... ; от ширины спрайта.
POP DE
EX AF,AF'
CALL DOWN_DE
EX AF,AF'
DEC A
JR NZ,LOOP1
RET
HL-адрес спрайта в памяти,
DE-адрес в экране,
A -высота спрайта в пикселях.
Этот способ несколько быстрее предыду-
щего, но из-за привязки к определенной
ширине спрайта, менее распостранен.
в.) Вывод графики при помощи стека.
Этот и следующий приемы вывода гра-
фики более эффективны и быстры по
сравнению с предыдущими, но вместе
с тем и несколько сложнее.
Итак, пересылка стек-экран:
Программа создает при первом запуске
рабочий блок , который собственно и
будет заниматься переброской графики.
Адрес графики заносится в регистр SP,
затем значения со стека последова-
тельно извлекаются и заносятся в эк-
ран. Примерно это будет выглдеть так:
...
POP HL
LD (#4000),HL
POP HL
LD (#4002),HL
POP HL
LD (#4004),HL
...
Естественно, что адреса, в которые
будет бросаться графика, заранее
фиксированы, фиксирваны также раз-
меры спрайта. Длина полученой проце-
дуры в памяти зависит от размеров
спрайта, и будет в два раза большей
чем он. То есть, если вы перебрасы-
ваете спрайт на весь экран (6144б.),
размер программы будет - 12288б.
Такое расточительство вполне
оправдано, так как скорость рабо-
ты этой программы гораздо выше чем
предыдущих. Один байт перебрасывает-
ся за 13 тактов. Тем более, что до
инсталляции программа будет занимать
всего каких-нибудь 100 байтов.
г). Следующий способ похож на прдыдущий,
но более подходит для скроллингов
вверх и вниз, чем для вывода графики.
Так как к определенным адресам здесь
привязывается и источник, и приемник.
...
LD HL,(#4100)
LD (#4000),HL
LD HL,(#4102)
LD (#4002),HL
LD HL,(#4104)
LD (#4004),HL
...
Абсолютно не используется стек и не
изменяет регистры, за исключением HL.
Использует на каждый перебрасываемый
байт графики по три байта памяти.
Один байт перебрасывается за 16 так-
тов.
д). Наиболее быстрым способом СКРОЛЛИНГА
экрана по вертикали и довольно совер-
шенным методом вывода графики из па-
мяти является следующий:
...
LD SP,адрес-источник
POP HL
POP DE
POP BC
POP AF
POP IX
POP IY
EXX
POP HL
POP DE
POP BC
LD SP,адрес-цель
PUSH BC
PUSH DE
PUSH HL
EXX
PUSH IY
PUSH IX
PUSH AF
PUSH BC
PUSH DE
PUSH HL
...
Этот метод очень эффективен, но все
равно не позволяет вывести весь экран
за одно прерывание.
е). Теперь рассмотрим САМЫЙ совершенный и
малоиспользуемый способ вывода графи-
ки:
Данные перемешиваются с программой,
и получается конструкция типа:
...
LD SP,адрес в экране
LD HL,два байта графики
PUSH HL
LD HL,очередные два байта
PUSH HL
LD HL,очередные два байта
PUSH HL
...
А теперь давайте немного посчитаем...
LD HL,число - 10 тактов,
PUSH HL - 11 тактов.
Для вывода полноэкранной картинки не-
обходимо повторить этот фрагмент
3072 раза = 21*3072 = 64512 тактов.
LD SP,число - 10 тактов.
Стек изменять придется ( хотя и не
обязательно ) перед выводом каждой
строки, то есть 192 раза = 10*192=
=1920 тактов.
И того, все в целом будет занимать
64512+1920=66432 такта !!!
Как видите, вполне реально вывести
изображение без повторений на целый экран
за одно прерывание.
Данный способ вывода графики далеко не
нов и придуман не мной. Во всяком случае
им пользовались многие мои друзья из RUSH,
и рассказал мне о нем IMP еще несколько
лет назад...
При использовании этого метода также
расходуется по два байта памяти на каж-
дый выводимый байт графики. Вывод пол-
ноэкранной картинки абсолютно без пов-
торяющихся фрагментов элементарно укла-
дывается не только в пентагоновское пре-
рывание, а и в прерывание на любой нор-
мальной машине, например, SCORPION, PROFI
и т.д. Правда на фирменной машине появ-
ляются проблемы связанные с тем, что в
ней раздельные поля памяти, то есть эк-
ранная память работает гораздо медленее,
а нам приходится помещать стек в экран...
Но если бы у фирменного SPECCY было ре-
ально 70000 тактов в прерывании, все от-
лично успевало бы работать, даже оста-
лось бы место для музыки.
Чтоб заставить изображение двигать-
ся, придется менять адреса, заносимые в
SP, но и это вполне реально.
И еще несколько полезных советов для
кодеров, которые были почерпнуты из мно-
голетнего опыта работы на ассемблере как
моего личного, так и многих других коде-
ров:
При выводе изображения по маске,
спрайт удобнее всего хранить перемешанным
с маской. Байт графики, затем байт маски
и т.д. Выводиться такой спрайт будет так:
...
POP DE ; два байта грфики
LD A,D
AND (HL)
OR E
LD (HL),A
INC L
...
Стек при этом должен указывать на графику,
а HL на экран.
Наиболее быстрый способ очистки эк-
рана:
LD SP,#5800
LD BC,0
PUSH BC - повторить 3072 раза.
Также можно очищать любые области в па-
мяти и т.п. Конечно вовсе не обязательно
делать такие процедуры абсолютно без цик-
лов. Можно, например, сделать всего 256
PUSH'ей, и зациклить этот блок нужное кол-
личество раз. Особых потерь в скорости
не будет.
Теперь очень важная вещь, которую
следует знать всем, кто решил писать ка-
чественные программы на SPECCY. При вы-
воде большого количества графики, веро-
ятность того, что телевизионный луч пере-
сечется с выводимым в данный момент бло-
ком графики очень велика. Это приведет
к тому, что в месте пересечения с лучем,
динамическое изображение будет дискри-
ровать. Например, при скроллинге боль-
шого фрагмента экрана верхняя часть его
будет сдвинута, затем луч "догонит" мес-
то вывода, и дальнейшая половина картинки
будет выводиться с отставанием на один
кадр. Еще более ужасная картина получа-
ется, если изображение на экране времменно
стирается, развертка может попасть именно
на такой момент, и тогда могут появиться
исчезающие спрайты, промигивающие курсоры
и прочее лэймерство.
Как с этим бороться:
Можно постараться, чтобы развертка не пе-
ресекалась с выводом на протяжении всего
прерывания. Так, можно сначала вывести
графику в среднюю и нижнюю трети экрана,
а в конце, когда лучь уже пройдет вер-
хнюю половину экрана, можно вывести верх-
нюю треть. Этот метод используется доволь-
но часто, но из-за огромных различий в
конструкции компьютеров развертка на раз-
ных типах SPECCY может сильно отличаться,
что станет причиной дискрирования изоб-
ражения. Стоит посмотреть как работает
"SHOCK" на Пентагоне, и вам все станет яс-
но.
Самым эффективным и практичным мето-
дом в данном случае является использова-
ние дополнительного экрана в машинах с
ОЗУ 128к и больше. Наличие двух экранов,
которые можно переключить мгновенно при
помощи одного единственного OUT'а, очень
сильно облегчает жизнь программисту.
Работа с двумя экранами производится
следующим образом: на прерывания (не обя-
зательно) вешается небольшая программа,
которая поочередно подключает то 7 стра-
ницу и обычный экран, то 5 страницу и
теневой экран. Выглядеть это может при-
мерно так:
SCREEN_CHANGER:
SCR LD A,#55 ; %01010101
RRCA
LD (SCR+1),A
LD A,#17 ; 16+7
JR C,PAGER
LD A,#1D ; 24+5
PAGER:
LD BC,#7FFD ; 32765
OUT (C),A
RET
Все процедуры, работающие с экраном,
должны быть написаны с учетом того, что
экран теперь находится не с адреса #4000
(16384 dec), а с адреса #C000 (49152 dec).
Процедуру DOWN_HL менять не нужно, она и
так будет работать корректно.
Суть данного метода состоит в том,
что изменять (стирать, двигать и т.д.) Вы
будете не тот экран, который отображается
в данный момент на мониторе, а тот, ко-
торый находится в памяти и не виден зри-
телю. Никакого, дискрирования не будет аб-
солютно, даже если Вы будете изменять весь
экран целиком. Так например сделано в сло-
вацкой демке "ECHOLOGY", и она великолепно
работает на всех машинах, вкючая Пентагон,
за исключением MULTICOLOR'ов, разумеется.
Кстати, MULTICOLOR - это и есть дискриро-
вание...
Конечно писать программы используя
один экран - круче, но на практике это
не целесообразно. Я советую Вам не мучить
пользователей и писать soft под два экра-
на.
А теперь совет, не имеющий прямого
отношения к работе с динамической графи-
кой, но он может пригодиться Вам в том
случае, если у Вас не хватает процессорно-
го времени на проигрывание музыки, а сво-
бодной памяти остается много. В таком
случае можно поступить следующим образом:
Музыка раскладывается на составля-
ющие компоненты и затем проигрывается ми-
нуя player. Простой вывод данных в порты
будет занимать каких-нибудь 300 тактов,
если сравнить с тем, что player от "ASM"
требует более 8000 тактов - разница ощу-
тима.
Желательно не подгружать уже разло-
женную на данные музыку с диска, а созда-
вать ее непосредственно перед запуском
программы , так-как размеры полученного
блока данных могут достигать десятков
киллобайт. Можно также попробовать ком-
прессировать повторяющиеся фрагменты.
Данный метод использовался во мно-
гих демонстрациях - "ECSTASY", "SHOCK",
"SATISFACTION", "INSULT" и др.
А вот наиболее красивый и компакт-
ный способ отключения звука на AY, который
я видел (писал его не я):
SHUT_UP:
LD HL,#000D
SHUT1 LD BC,#FFFD
OUT (C),L
LD B,#BF
OUT (C),H
DEC L
JR NZ,SHUT1
RET
В том случае, когда вам необходимо оп-
ределить нажатие любой клавиши, включая
Caps Shift и Simbol Shift очень удобно
пользоваться "классической" процедурой из
ПЗУ, которая находится по десятичному ад-
ресу 654. Процедура возвращает в регистре
Е код 255 (#FF) , если не нажата ни одна
клавиша.
Пример использования:
WAIT:
CALL 654
INC E
JR Z,WAIT
RET
Если кто-то не понял, что именно я
имел в виду под процедурой DOWN_HL или
DOWN_DE, я привожу ниже их текст:
DOWN_HL:
INC H
LD A,H
AND 7
RET NZ
LD A,L
ADD A,#20
LD L,A
RET C
LD A,H
SUB 8
LD H,A
RET
DOWN_DE:
INC D
LD A,D
AND 7
RET NZ
LD A,E
ADD A,#20
LD E,A
RET C
LD A,D
SUB 8
LD D,A
RET
Если Вам нужно опуститься вниз на целое
знакоместо, нужно выполнить следующие дей-
ствия (адрес в HL), а не вызывать восемь
раз в цикле DOWN_HL, как делают некоторые
наивные ребята... :
LOWER_HL:
LD A,L
ADD A,#20
LD L,A
RET NC
LD A,H
ADD A,8
LD H,A
RET
Иногда бывает нужно пересчитать адрес в
экране в адрес соответствующий данному
знакоместу в области атрибутов. Сделать
это можно так:
SCR_ATR:
LD A,H
RRCA
RRCA
RRCA
AND 3
OR #58
LD H,A
RET
На сегодня хватит... Конечно спосо-
бов повышения эффективности программ
может быть бесконечное множество. Для
каждого конкретного случая есть свои при-
емы и тонкости. Их нужно знать не только
для того, чтобы писать сногсшибательные
эффекты...
Не умея пользоваться достижениями
современных кодеров, вы не сможете писать
качественные динамические игрушки, да и
хорошей системной программы написать не-
возможно, пользуясь методами десятилетней
давности.
Поэтому дерзайте ! Возможно, скоро
Вам удастся написать полноэкранный multi-
color или еще какое-нибудь чудо кодинга !
Good luck !!!
Contenido de la publicación: Rush #01
- AMIGA NOTICIAS
Amiga Inc trabaja en Amiga OS 3.5 con mejoras como soporte de unidad de CD y PowerPC. Desarrollo dividido para procesadores M68K y PPC. Lanzamiento retrasado a finales de 1999 o principios de 2000.
- NOTICIAS AMIGA
Descripción del visor 'Fast JPEG 1.10' para Amiga, enfocándose en sus características, instalación y uso. Destaca ventajas como el procesamiento rápido sin pérdida de calidad y ofrece consejos para el usuario. Se invita a los lectores a compartir sus experiencias con el software.
- AMIGA NOTICIAS
Programación básica para Amiga clásica, discutiendo desafíos y compartiendo conocimientos en codificación Amiga. Resumen de capacidades gráficas de Amiga y características del procesador. Introducción a las especificidades del lenguaje ensamblador de Amiga.
- AMIGA NEWS
Resumen de eventos relacionados con la plataforma Amiga desde principios hasta mediados de 1998. Incluye nuevos hardware, lanzamientos de software y colaboraciones destacadas de empresas. Se planifican futuras actualizaciones y desarrollos para el próximo número.
- NOTICIAS DE AMIGA
Colección de trucos y secretos para juegos clásicos de Amiga recopilada por Postcard Man. Se anima a los lectores a compartir sus hallazgos sobre juegos complejos. Se proporciona selección de consejos y códigos de niveles para varios juegos.
- AMIGA NEWS
Discusión sobre las tarjetas gráficas de Phase-5 y las capacidades del procesador Permedia 2. Detalles sobre la aceleración 2D/3D del Permedia 2 y su compatibilidad. Mención de los procesadores GLINT Delta y comparación de precios y disponibilidad.
- NOTICIAS DE AMIGA
Análisis de la supervivencia de Amiga en los 90, destacando los esfuerzos de la comunidad y los avances tecnológicos. Discusión sobre mejoras de hardware y desarrollo de software. Aliento para una mayor exploración y aprendizaje sobre la plataforma Amiga.
- Programación para Spectrum
Explicación de un método rápido para gráficos 3D en tiempo real en el ZX Spectrum. Introduce técnicas eficientes de rotación y deformación para objetos 3D. Destaca mejoras sobre métodos tradicionales con ejemplos prácticos.
- Programación de Spectrum - Ticklish Jim
Discusión sobre la combinación de efectos de sonido con música para el chip AY de Spectrum. Ejemplos del desarrollo de 'CSC: Deja Vu' y desafíos técnicos enfrentados. Contiene guía práctica y ejemplos de código.
- Programación de Spectrum
Discusión sobre el reflejo de bytes y la restauración de fondo en la programación de ZX Spectrum, con ejemplos.
- Programación para Spectrum
Guía completa para programadores de sistemas con consejos prácticos para crear software eficiente y fácil de usar, incluyendo técnicas de codificación, compatibilidad con dispositivos y estrategias de prueba de programas.
- Programación para Spectrum
Técnicas avanzadas de codificación y métodos modernos de gráficos para ZX Spectrum. Consejos para optimizar procedimientos gráficos y codificación en ensamblador. Consejos útiles para programadores para mejorar el rendimiento y la eficiencia.
- El Final
Reflexiones sobre la creación del primer número de la revista 'Rush', sus objetivos, audiencia y desarrollo futuro.
- ZX-SOFT - Вячеслав Медноногов
Actualizaciones de desarrollo del nuevo juego 'Black Raven II' de Vyacheslav Mednoy, incluyendo cambios en la jugabilidad, introducción de nuevos hechizos y mejoras de rendimiento.
- ZX-SOFT
Descripción general de las nuevas funciones en el comandante actualizado de REAL software para ZX Spectrum, incluyendo gestión de archivos, autodetección y visualización de medios. Mejoras en el manejo de texto, fuente y música. Se abordan preguntas sobre futuras actualizaciones.
- ZX-SOFT
Debate sobre qué demo merecía el primer puesto en Funtop'98: Forever de DR o Refresh de XTM. Las discusiones en la comunidad demoscene destacan el choque entre destreza técnica y profundidad conceptual. Las diferentes opiniones reflejan la evolución de las preferencias en la demoscene.
- Autores
Reconocimiento a colaboradores y socios en la creación de la revista Rush. Detalle de roles de cada autor y colaboraciones. Reconocimiento a soporte técnico y asociaciones mediáticas.
- Specky Virtual
Discusión sobre la conversión de gráficos de PC a Spectrum, con opiniones de varios expertos. Se detallan técnicas para mejorar la calidad de conversión y herramientas como Photoshop. Énfasis en el refinamiento post-conversión en editores gráficos de Spectrum.
- Espectro Virtual
Discusión sobre el emulador CBSpeccy para ZX-Spectrum en Amiga, destacando sus características, opiniones de la comunidad y rendimiento técnico. Críticas y elogios por sus capacidades de emulación, en particular en comparación con los emuladores de PC. Examen de posibles mejoras y debates comunitarios sobre las actualizaciones de versión.
- Espectro Virtual
FAQ sobre la emulación de ZX-Spectrum en PC, cubriendo emuladores populares y formatos de archivos. Instrucciones para usar diferentes emuladores y gestionar tipos de archivos como Hobeta y TR-DOS. Discusión sobre servidores y recursos rusos orientados al ZX.
- Introducción
Introducción a la revista Rush, enfatizando la creatividad, la escena progresiva y el objetivo de crear una fuente de información superior. La revista busca reunir grupos prometedores y ofrecer una perspectiva única. Se enfoca en el contenido y la atmósfera, invitando a los creadores a contribuir.
- Introducción - Grunge
Introducción a Rush, una nueva revista para entusiastas de Speccy/Amiga, busca ofrecer contenido de calidad y noticias mientras fomenta la retroalimentación de los lectores.
- Entrevista - Konex
Entrevista con el grupo ANTARES después de FUNTOP-98. Discusión sobre sus demos, desafíos y planes futuros. Perspectivas sobre la formación y dinámica del grupo.
- Entrevista - Kvazar, DUX
Entrevista con Alexander Seleznev (KVAZAR), discutiendo su historia con las computadoras, el estado de la escena ZX Spectrum y planes futuros.
- Entrevista - Kvazar
Entrevista con el grupo de Vitebsk POWER sobre la demo 'Crazy Love', experiencias de desarrollo y proyectos futuros.
- Informatorium
Exploración de un CD con emuladores para varias plataformas, destacando Spectrum. Detalla la organización y diversidad de contenidos. Concluye con ideas del CD-ROM Project y su colección de software Spectrum.
- Informacrium
Compilación de direcciones de Internet interesantes y útiles relacionadas con recursos de Amiga, incluyendo revistas, fabricantes de hardware y empresas de software.
- Informacrium - Viator
Resumen de las publicaciones existentes y futuras sobre la plataforma Amiga. Discusión sobre la disponibilidad y los desafíos de distribución de la literatura Amiga. Llamado a la colaboración con nuevas publicaciones.
- Sobre la Revista
Discusión sobre la creación de una revista multiplataforma centrada en Spectrum, Amiga y PC. Énfasis en una comprensión más amplia de la escena informática. Fomentar el profesionalismo y la adaptación a la tecnología cambiante.
- Mundos Paralelos
Descripción de la evolución del sistema operativo Windows y los procesadores de PC de 1981 a 2000. Hitos en el desarrollo de MS-DOS, Windows, procesadores Intel y competencia con AMD y Cyrix. Desafíos para mantener la compatibilidad con nuevas tecnologías de procesadores.
- Mundos Paralelos
Resumen de modelos Macintosh y su relevancia en los campos de diseño y gráficos, cubriendo precios y especificaciones de 1997-1998. La discusión incluye la evolución del hardware de Apple, notablemente la serie PowerMac, y compara los nuevos procesadores G3 con sus contrapartes de PC. Destaca el resurgimiento de Macintosh después de la crisis y su influencia continua en el mercado.
- Desarrollo del Spectrum - Slider
El artículo analiza una nueva extensión gráfica para el ZX Spectrum que mejora las paletas de colores sin aumentar las demandas de recursos. Al usar una señal de flash modificada, se crean nuevos colores sin interferir con la compatibilidad del software existente. El artículo proporciona detalles de implementación y aborda preocupaciones sobre el uso práctico.
- Desarrollo del Spectrum
Conexión de un módem CDOS al ordenador 'Compact-128' abordando conflictos de puertos del teclado. Descripción de modificaciones de hardware para resolver el problema. La solución incluye bloqueo automático mediante un inversor de transistor.
- Desarrollo de Spectrum - Ars
Discusión sobre el desarrollo de AZX-Monstrum 512K, su compatibilidad de hardware, opciones de procesador y posibles mejoras en gráficos y sistema operativo.
- Desarrollo de SPECTRUM
Discusión sobre la nueva plataforma informática de Clive Sinclair, la ZX2000, diseñada para superar a las PC con mayor velocidad, asequibilidad y eficiencia de batería.
- Desarrollo del Spectrum - Андрей Савичев
Examen de la evolución y la relevancia continua del procesador Z80 y su papel en los sistemas embebidos. Comparación del Z80 con sus sucesores, destacando ventajas como eficiencia energética y mejoras de comando. Resumen de CPUs integrados basados en Z80 y sus periféricos.
- Anuncio
Este artículo es un anuncio de productos de Scorpion, incluyendo hardware para ZX Spectrum y software para Amiga, junto con detalles de precios y pedidos.
- Publicidad
Colección de anuncios para hardware y software de Amiga y ZX Spectrum, con información de contacto para vendedores y detalles sobre la nueva suscripción a la revista Amiga.
- Anuncio
Anuncio de la placa de música General Sound de X-TRADE. Incluye precios, detalles técnicos e instrucciones de compra. Presenta una sección de preguntas frecuentes e información de compatibilidad.
- Sentido Sin Sentido - Viator
Reflexiones filosóficas sobre el existencialismo, la inmortalidad y el destino humano. La narrativa teje historias de ambición, la búsqueda de la vida eterna y una caída utópica. Una mezcla de introspección y ficción especulativa.
- Escena vs Profesionales
Exploración de la creatividad de la demoscene frente al desarrollo comercial de juegos. Discusión sobre el potencial para programas de calidad profesional por miembros de la escena. Llamado a la colaboración con grupos destacados de la escena.
- Crónica de la Escena - Андрей Савичев
Reflexiones sobre el atractivo perdurable del ZX Spectrum, la resiliencia de su comunidad y su posible resurgimiento en Rusia.
- Cronología de la Escena
Descripción general de las actividades del grupo Rush, incluidos proyectos pasados, esfuerzos actuales y planes futuros, con énfasis en el desarrollo de software y juegos.
- Crónicas de la escena
El artículo analiza varias noticias de la escena ZX Spectrum, incluidas lanzamientos de juegos, demoparties y actualizaciones de desarrolladores y equipos.
- Crónicas de la Escena
El artículo trata sobre el festival internacional de arte computacional FUNTOP'98 que se celebró en Moscú, destacando los eventos clave, asistentes notables y las distintas competiciones celebradas durante el evento.
- Escena Cronia
Discusión sobre el desarrollo de la escena Amiga a través de la colaboración, abordando el aislamiento del usuario y promoviendo la expansión de la red.
- Gestión de la Interfaz
El artículo describe el control de la interfaz para ZX Spectrum y Amiga, incluidos las teclas y funciones de navegación. Se mencionan características de funcionamiento en Amiga con monitores PAL y se proporciona un contacto para soporte. También se señala que los archivos de texto tienen codificación estándar MS-DOS.
